WORLD 
	NAME		Map Demo
	IMAGESFOLDER    http://www.dimensionex.net/pics/
	VERSION 1.1
	'
	'
	' This is actually a reduced version of "The Beach"
	' Please note:
	' - The MAP tag in the GUI section
	' - The mapx,mapy ATTRibutes in all the ROOMS definition
	'
	' Easy!
	

GUI
	SCENE SIZE	350x235
	SCREEN SIZE	640x480
	LOGOSRC		thebeachfront.jpg
	MSGLISTSIZE	3
	SKINS		default,forest.dxs,castle.dxs
	MAP		map.jpg

PANEL def1
	BUTTON panswitchm, "Show map >>", "Show map!", doSwitchPanelMap

PANEL pmap
	MAP
	BUTTON panswitchd, "Hide map <<", "Hide map!", doSwitchPanelDef
	LABEL "<BR>"

END_GUI

' **************************************************************
ROOMS
' **************************************************************

ROOM spiaggia
	NAME	The beach
	DESCRIPTION	A beautiful beach stands before my eyes.
	IMAGE 		scnBeach3.jpg
	ATTRLIST	mapx=27,mapy=128

ROOM spiaggia2 DEFAULT
	NAME	The beach and the palm trees
	DESCRIPTION	This is the classic beach made of white sands and palm trees... an old cliché but quite effective anyway.
	IMAGE 		scnBeachpalm.jpg
	ATTRLIST	mapx=25,mapy=86

ROOM spiaggia3 
	NAME	The beach and the boats
	DESCRIPTION	A beautiful beach stands before my eyes. The boats are somehow bound to the shore.
	IMAGE 		scnBeachboats.jpg
	ATTRLIST	mapx=26,mapy=73
	

ROOM spiaggia4
	NAME	The beach and the rocks
	DESCRIPTION	The rocks shine in the sun and the weather now it's the right one to have a bath.
	IMAGE 		scnBeachrock.jpg
	ATTRLIST	mapx=50,mapy=156

ROOM rocca
	NAME	The cliff
	DESCRIPTION	From here you can enjoy the beautiful landscape of the beach below.
	IMAGE 		SHOWAREA -1,-1,0	scnSpiaggiaDasopra.jpg
	ATTRLIST	mapx=73,mapy=128
	
ROOM bar
	NAME	The beach bar
	DESCRIPTION	This must be the ideal place for a refreshing drink. Latin music is playing at loud volume.
	IMAGE 		beachbar.jpg
	ATTRLIST	mapx=50,mapy=64

ROOM kitchen
	NAME	Bar interiors
	DESCRIPTION	The bar's inner room is well equipped for a busy afternoon. There's a door, up there at right side.
	IMAGE 	SHOWAREA 185,280,55	scnbarinterior.jpg
	ATTRLIST	mapx=61,mapy=64

ROOM beachcliff
	NAME	The cliff's bottom
	DESCRIPTION	I can somehow climb up here quickly, even though it's not quite comfortable. The sea is at my shoulders.
	IMAGE 	E	scnbeachcliff.jpg
	ATTRLIST	mapx=63,mapy=128

END_ROOMS


' **************************************************************
LINKS
' **************************************************************


MLINK	w5	kitchen-beachcliff	E
	NAME		door
	ICON		icoDoor.gif

MLINK	w4a	spiaggia3-bar	E
	NAME	to the bar
MLINK	w4b	bar-spiaggia3	W
	NAME	to the beach

LINK	w7	bar-kitchen	E

MLINK	w6	bar-bar	D
	NAME	a trapdoor
	ATTRLIST	open=0,locked=1
	ICON		trapdoor.gif
	DESCRIPTION	a square-shaped trap door, connects the bar with the bar's cellar!
	IMAGE		41x30	td.gif
	SHOW		ONSCREEN	200,5

LINK	w16	spiaggia-beachcliff		E

MLINK	w16a	beachcliff-rocca		U
	NAME	to the cliff

MLINK	w17	rocca-spiaggia			D
	NAME	to the beach
LINK	w24	spiaggia2-spiaggia3		N
LINK	w25	spiaggia-spiaggia2		N
LINK	w26	spiaggia-spiaggia4		W


END_LINKS


' **************************************************************
CHARACTERS
ATTRLIST Health=10,Skill=1
' **************************************************************


CHARACTER surfer
	NAME		a surfer
	DESCRIPTION	Walks up and down, I'd say he's got nothing to do.
	POSITION	RndSet(setBeach)
	IMAGE		110x110		chrSurfista.gif

CHARACTER tommy
	NAME		Tommy
	DESCRIPTION	He's enjoying some loudpumping music..
	IMAGE		45x100		punkjamming.gif
	POSITION	kitchen
	ACCEPTS		apple

CHARACTER barman
	NAME		the barman
	DESCRIPTION	He's standing as he'd expect me to order a drink.
	POSITION	bar
	IMAGE		100x118	chrbarmanmir.gif
	SHOW		ONSCREEN	250,40

END_CHARACTERS


ITEMS

' ************************
' Switches and controls
' ************************

ITEM switch1
	NAME		a switch
	DESCRIPTION	It is a switch mounted on the wall...
	POSITION	kitchen
	ICON		icoInterruttore.gif
	ATTRLIST	hideable=0
	IMAGE		77x111	interruttore.gif
	SHOW		ICON 120,138

END_ITEMS


' **************************************************************
SETS

SET setBeach	spiaggia,spiaggia2,spiaggia3,spiaggia4

END_SETS

' **************************************************************
SCRIPTS
' **************************************************************

EVENT bar.onReceive
ACTIONS
	' Plays the background music only once
	If $TARGET.barmusic = 1
		Return
	Else
		PlayBackground "apuertas.mid"
		$TARGET.barmusic = 1
	End_If



EVENT surfer.onLook
ACTIONS
	Speak "I'm waiting for the waves to grow, you know.", "SO WHAT?", "What a wonderful day!","Please leave me alone, I'm very busy!","Once I was a computer programmer, it was very different than today!"



EVENT surfer.onHear
ACTIONS
	If $TARGET = "gun please" And gun.container = $OWNER
		Speak "Yes sir!" 
		Move gun, $AGENT
	Else
		Speak "There's a locked gate up on the hill. You can't escape this place, it seems.", "You know what? I've been told that there's a switch somewhere in the bar which unlocks that gate.", "I never managed to find it, though."
	End_If


EVENT barman.onLook
ACTIONS
	If $OWNER.empty
		Speak "Sir, we only have got canned drinks... well... WE DID!","I GOT NOTHIN'TO GIVE YOU! SCRAM!"
	Else
		Speak "Hey boy, wanna something to drink?", "Are you thirsty? We've got LOTS of great cocktails!"
	End_If

EVENT doSwitchPanelMap
	SetPanel $AGENT,"pmap"
End_EVENT


EVENT doSwitchPanelDef
	SetPanel $AGENT,"def1"
End_EVENT

EVENT onNew
	Speak "Welcome to " + name + ", " + $AGENT.name + "!"
	SetPanel $AGENT,"def1"
End_EVENT

END_SCRIPTS

END_WORLD